如果有url，请将单元格变成超链接

我在Excel中有一个表单，其中包含名称，名称旁边的“some”是一个URL。

该名称然后在另一个工作表中使用，可能会继续到其他单元格中。

基本上，这是一个游泳锦标赛，获奖者会在比赛的后续阶段进行，我想要发生的是，如果表单中有一个URL，可以将其名称的实例变成超链接。

我知道这个vlookup，HYPERLINK（）和if等等，但把它们连接在一起，实际上它正在损害我的大脑！

单元格D68目前包含：

=IF(E4<>"",IF(E4<F4,G4,D4),L4&" - "&M4)

第一张

表二 – 名称的第二个实例

Answer 1

从你的问题中不清楚你想要放置公式的位置，所以我假定你想把公式添加到图片eG2fj.png中。

我build议把这个公式分成几部分来处理。 我相信你的公式应该由以下内容组成：

 =IF(use VLOOKUP to see if user has an associated link, "Link exists so show name as hyperlink", "Link doesnt exist so just show the name") 

现在单独构build零件，首先是VLOOKUP

 =VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0) 

这将在'C2mp6'!$A$2:$B$7中的单元格D68中查找名称，如果有完全匹配，则返回第二列中的值。

对于公式的第一部分，我们只需要testing它是否为空。 也就是说，如果链接已经提供或没有。 如果提供链接，下面将返回TRUE，如果链接没有提供，则返回FALSE：

 =VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0) <> "" 

现在回到完整的公式：

 =IF(VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0) <> "", "Link exists so show name as hyperlink", "Link doesn't exist so just show the name") 

现在要处理链接存在的情况，即TRUE。 要做到这一点将使用HYPERLINK 。 首先testing它自己的。 第一个参数是从前的VLOOKUP （即链接，因为这是TRUE，我们知道链接已填充），第二部分是如何显示链接，即玩家的名字：

 =HYPERLINK(VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0), D68) 

一旦这个工作，添加到完整的公式：

 =IF(VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0) <> "", HYPERLINK(VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0), D68), "Link doesn't exist so just show the name") 

最后掩盖如果链接不存在会发生什么。 尽pipe你可能认为你可以添加一个单元格参考玩家的名字，这实际上是一个问题，因为excel仍然认为它是一个超链接。 相反，我们需要添加一个“虚拟”超链接，这个超链接只是引用玩家的名字。 例如：

 =HYPERLINK("#"&CELL("address", D68), D68) 

最后加上这个：

 =IF(VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0) <> "", HYPERLINK(VLOOKUP(D68, 'C2mp6'!$A$2:$B$7, 2, 0), D68), HYPERLINK("#"&CELL("address", D68), D68)) 

希望这可以帮助